TannieSpace » applescript

Snoozing, deferring and other things in OmniFocus

tanja

A while back I wrote about snoozing and deferring tasks in OmniFocus and Dan’s scripts. He has since added two more scripts, to move tasks to today and tomorrow quickly. Sometimes I don’t check my task-list for a few days (for whatever reason) and then I may ==cough== have tons of overdue items. These two scripts easily let me put them on the right day, either today or tomorrow, and helps me clean up fast.

I’ve set up the same shortcut keys in Fastscripts.

Today I’ve also edited my task-list. I had too many things on them and felt overwhelmed. After listening to one of Michael Nobbs’ audioboo in which he mentioned his three things to do list and the twenty minute trick (I go for fifteen), and also mentioned that once something becomes a habit he just does it and doesn’t add it to the list anymore, I decided to remove a few items that I know I do anyway. It looks much smaller and much easier to manage.

I might actually go and do something today…

Create a new task in a project

tanja

For completion sake, I decided to post the bit to create a new task in a new or existing project in OmniFocus through AppleScript. I have this in my script that creates tasks from my mail.

If you know a bit of AppleScript, this should help out. If I have the energy, I might post the entire script later and explain the parts.

In this case, it took longest to figure out the following part:

tell MyProject
set theTask to make new task with properties¬
{name:MyTaskTopic, context:MyContext, note:ThisNote}
end tell

Apparently, when creating a new task you have to tell the project. If you want to set the context, you instead tell the task to set its context property to something.

This does make sense, in the way that you always tell the containing item to do something.

The part I use in my script:

if MyContext is equal to "NONE" and MyProject is equal to "NONE" then
set theTask to make new inbox task ¬
with properties {name:MyTaskTopic, note:ThisNote}
set ProjectString to "INBOX"

else if MyContext is equal to "NONE" and ¬
MyProject is not equal to "NONE" then
tell MyProject
set theTask to make new task ¬
with properties {name:MyTaskTopic, note:ThisNote}
end tell

else if MyProject is equal to "NONE" and ¬
MyContext is not equal to "NONE" then
set theTask to make new inbox task ¬
with properties {name:MyTaskTopic, context:MyContext, note:ThisNote}
set ProjectString to "INBOX"

else
tell MyProject
set theTask to make new task ¬
with properties {name:MyTaskTopic, context:MyContext, note:ThisNote}
end tell
end if

try
set Datum to setDueDate
set due date of theTask to setDueDate
on error
set due date of theTask to ((current date) + 604800)
end try

tell theTask
set note to return & return
tell note
set theURL to "message://< " & message_id & ">"
set linkText to theURL
insert linkText at before first character
set value of attribute "link" of style of paragraph 1 to theURL
insert message_content at before last character
end tell
end tell

which works like a charm.

Applescripts for OmniFocus: change the context or project of selected tasks.

tanja

I use OmniFocus a lot, and have recently tweaked some more AppleScripts to make my workflow even more smooth. I can add any mail to OmniFocus for replies, add confirmation of orders from mail to OmniFocus which will automatically go into my project-shoebox for orders, with a ‘waiting for’ context and a due date set to 1 week into the future, unless I’ve changed or added MailTags with a project, a keyword and a due date. In that case it’ll take the project, the first keyword and the due date and use them to set up the OmniFocus task. I have a few more scripts:

in OmniWeb I can take and add a URL for later reading, it’ll go into my inbox by default
in OmniWeb I can take and add a URL to my ‘wish-list’ project (with a start date for at 2 weeks in the future)
in OmniFocus I have scripts to easily change the context or the project of selected tasks
in Mail I can press a key and have the selected e-mail(s) sent to OmniFocus with a ‘Respond to: ‘ before the subject line, sorting into either a default project or the one specified in MailTags, with the context set to ‘mail’ and the message URL in the note-field
in OmniFocus I can select such a task, press a key to run a script that will open the message and immediately create a reply (I have a separate one for just opening, in case I have to read it thoroughly first)

All these scripts make the integration between all these programs very easy. That and FastScripts.
I found useful scripts over at Curtis Clifton’s site. His scripts use Growl notification so if you have Growl installed you get a small notification.

I had some trouble putting my own scripts together, so I decided to paste the info here, just in case I need it later on, or someone else runs into similar issues. I found it quite hard to figure out how to add a task to an existing project or to move it from inbox / other project. In the end, it only took a few lines.

First, when I started my script, I wanted a default project or context (I’ll use ‘project’ from now on, but it also applies to the context-script). To do this I created a ‘property’ at the beginning of the script:

property defaultProject : "Miscellaneous"
property alertItemNum : ""

I used the alterItemNum for my alerts through this very simple routine:

on notify(alertName, alertTitle, alertText)
display dialog alertText as string with icon 1
end notify

That went at the end of my script.

I started by addressing OmniFocus and ‘talking’ to the open document:

tell application "OmniFocus"
tell front document
tell (first document window whose index is 1)

Then, I checked to see if that document had anything selected, and if not, give an error-dialogue:

set SelectedItems to selected trees of content
set numItems to (count items of SelectedItems)
if numItems is 0 then
set alertName to "Error"
set alertTitle to "Script failure"
set alertText to "No valid task(s) selected"
my notify(alertName, alertTitle, alertText)
return
end if

If I have no items selected, the script will call the alert routine from above ( my notify(alertName, alertTitle, alertText) ). Because I created a separate routine, I can use this anywhere in the script.

Next, display a dialogue asking for the project:

display dialog "Change to what Project? " default answer defaultProject buttons {"Cancel", "OK"} default button 2

set theProject to (the text returned of the result)

The variable ‘theProject’ will now contain the name of the (new) project to move the tasks too.

Next, the loop to go through all the items and move them:

set selectNum to numItems
set successTot to 0
repeat while selectNum > 0
set selectedItem to value of item selectNum of SelectedItems
set succeeded to my ChangeProject(selectedItem, theProject)
if succeeded then set successTot to successTot + 1
set selectNum to selectNum - 1
end repeat

This loop will end as soon as the variable ‘selectNum’ (= numItems which I set to the count of the items in the variable SelectedItems) reaches 0. It calls the routine ‘ChangeProject’ which I’ll get to in a bit, but I first want to wrap up this part. Let me also explain the ‘if succeeded then set successTot to successTot + 1′ line. The line before sets ‘succeeded’ to the result of the ChangeProject routine. This result can mean anything, numbers, letters, whatever. In this case we use it to return a ‘true’ or ‘false’. That way, we only need to use ‘if succeeded’ (which will either be ‘true’ or ‘false’) as a condition. We don’t need to check the actual content of the variable. This can come in handy for various checks, and it took me a while to catch on to that, so I figured I’d mention it here.

To end this main routine, I used:

set alertName to "General"
set alertTitle to "Script complete"
if successTot > 1 then set alertItemNum to "s"
set alertText to successTot & " item" & alertItemNum & " changed to Project " & theProject
end tell
end tell
my notify(alertName, alertTitle, alertText)
end tell

Basically, this tells the dialogue box to say the script ran successfully and displays the number of items successfully moved and only to use the ‘s’ after ‘item’ if the count of successful moves is higher than 1.

That wraps up the main part.

The routine to actually move the task to the other project only took 21 lines:

on ChangeProject(selectedItem, theProject)
set success to false
tell application "OmniFocus" to tell default document
if (theProject is not "") then
set MyProjectArray to null
set MyProjectArray to complete theProject as project maximum matches 1
try
set MyProjectID to id of first item of MyProjectArray
set theNewProject to project id MyProjectID
on error
set theNewProject to (make project with properties {name:theProject})
end try
try
set newtask to selectedItem
move newtask to end of tasks of theNewProject
set success to true
end try
end if
end tell
return success
end ChangeProject

The first line sets the success to ‘false’, because we want to actively, after having our success, set it to ‘true’.
We then chat with OmniFocus again, and this time, we’ll just talk to the default document (the one you have open). If the variable ‘theProject’ is not empty, we’ll continue. If it is, the ‘if-end if’ ends, without having set the ‘success’ variable to true (and thus, the script failed). You could technically build in an extra loop to change it to a default project, however, I prefer it this way. If I accidentally emptied that dialogue-box, nothing will happen, just as I like it.

If theProject does contain something (anything), the script continues with its routine. It sets the MyProjectArry to null (makes it empty, just in case). It then used OmniFocus complete option to find the first matching project of OmniFocuses project-list. If you’ve ever only typed the first three letters in one of OmniFocus’s project-areas (to set the project) and it magically came up with the right project, this is the same thing. It means you only have to type the first three or four letters of your project, and the script will find it. If it can’t find the project, it will create it for you (at the end of your project-list).

After that, it will simply try to add the task to the desired project.

try
set newtask to selectedItem
move newtask to end of tasks of theNewProject
set success to true
end

I’ve copied this part again, because this took me hours to figure out. I knew how to do it for a context-change:

try
set newtask to selectedItem
set context of newtask to theNewContext
set success to true
end try

so I tried to ‘set project of newtask to theNewProject’ but that didn’t work. It drove me crazy for a while, still haven’t fully recovered…

But it works! The complete script changes the project of selected tasks and gives a confirmation dialogue (so you know that it happened). Of course, before using it, make a back up of your OmniFocus database, and run the script from Script Editor first. Open the ‘Event Log’ (⌘-3) to follow what happens while you run the script.

zipped up version of ChangeProject and ChangeContext for easy downloading

Bit.ly + TextExpander + Applescript = WIN!

tanja

I wanted an easy way to shorten my URLs through one of the URL-shorteners out there. I liked bit.ly, because it’s nice and short, has an easy to navigate web-interface (without a mouse) and I can use its magic with my terminal (cURL).

I also very much like TextExpander and after googling a bit, I ofcourse found an Applescript for TextExpander and Bit.ly. That link also shows how to set it up in TextExpander, very handy! The script does not however use your actual bit.ly account so you can keep track of the URLs you shorten. I tweaked it and made adjustments and it took hours and ofcourse, then I find this which is almost exactly what I had, except with URL-encoding (yummy). The only problem with that one was that I couldn’t get it to have the URLs show up in my recent history. The ‘history=1′ didn’t seem to work.

I tweaked some more and came up with something that completely does what I want. I use OmniWeb so I replaced the

set the PageURL to (the clipboard as string)

with

tell application "OmniWeb"
set PageURL to address of active tab of browser 1
end tell

If you use safari, use

tell application "Safari"
set PageURL to URL of front document
end tell

I’ve made this as readable as possible, the ‘¬’ do matter in Applescript.

tell application "OmniWeb"
set PageURL to address of active tab of browser 1
end tell

set login to "YOUR LOGIN"
set api_key to "YOUR API KEY"
set the EncodedURL to urlencode(PageURL) of me

set curlCMD to ¬
"curl --stderr /dev/null \"http://api.bit.ly/v3/shorten?format=txt&longUrl=" ¬
& EncodedURL & "&history=1&login=" & login ¬
& "&apiKey=" & api_key ¬
& "\""

-- Run the script and get the result:
set bitlyURL to (do shell script curlCMD)

return bitlyURL

on urlencode(theText)
set theTextEnc to ""
repeat with eachChar in characters of theText
set useChar to eachChar
set eachCharNum to ASCII number of eachChar
if eachCharNum = 32 then
set useChar to "+"
else if (eachCharNum ≠ 42) and (eachCharNum ≠ 95) ¬
and (eachCharNum < 45 or eachCharNum > 46) ¬
and (eachCharNum < 48 or eachCharNum > 57) ¬
and (eachCharNum < 65 or eachCharNum > 90) ¬
and (eachCharNum < 97 or eachCharNum > 122) then
set firstDig to round (eachCharNum / 16) rounding down
set secondDig to eachCharNum mod 16
if firstDig > 9 then
set aNum to firstDig + 55
set firstDig to ASCII character aNum
end if
if secondDig > 9 then
set aNum to secondDig + 55
set secondDig to ASCII character aNum
end if
set numHex to ("%" & (firstDig as string) ¬
& (secondDig as string)) as string
set useChar to numHex
end if
set theTextEnc to theTextEnc & useChar as string
end repeat
return theTextEnc
end urlencode

ETA (2010.09.30): bit.ly changed a few things so I changed the script above to reflect that

OmniWeb now free!

tanja

Once again I got frustrated with Firefox and Safari for numerous reasons. I went over to the OmniGroup site to check out OmniWeb cause I really liked using its demo. I wanted to see what price they charged and see if I would want to part with that (next month) to solve my frustrations with The Other Browsers.

And they made it free. I suck for only finding out now, three weeks after they made it free, but at least it means I can have my lovely browser that supports applescript and Services (looking at you, Firefox!), doesn’t take ages to load a page (again, looking at you, Firefox!) and supports non-mouse browsing (Firefox! no wait, that’s actually Safari….).

Very happy :D

Postponing tasks in OmniFocus (and snoozing)

tanja

For a while I’ve wanted to easily postpone tasks in OmniFocus because sometimes, I just want to procrastinate a little.
Last night I started fiddling and playing with AppleScript to get this done and after a few hours of that I wanted to rip my hair out. I went to bed instead because I quite like my hair intact and had a few other things to do today, so didn’t get around to it until now. I applied my google-foo to try and fix the problems I ran into.

And ‘lo and behold! I found Dan’s site who did not only make a script to postpone the due date (defer it), it also gives you the option to defer the start date and he made a nifty little snooze script to basically hide projects / tasks from your view until you have to do them (by adjusting the start date).

I’ve tossed both in my ~/Library/Scripts/Applications/OmniFocus folder and set up a hotkey in QuickSilver and tried it out on a few tasks. Works like a charm!